PROC LOGISTIC DATA=donner PLOTS=(DFBETAS INFLUENCE PHAT);
  CLASS Status Sex;
  MODEL Status = Sex|Age;
  OUTPUT OUT=dgn C=C;
RUN;

PROC SGPANEL DATA=dgn;
  PANELBY Sex;
  NEEDLE X=Age Y=C / LINEATTRS=(THICKNESS=3) GROUP=Status;
RUN;

** Correlation of design matrix;
PROC LOGISTIC DATA=donner OUTDESIGN=X;
  CLASS Status Sex(PARAM=REF REF="Female");
  MODEL Status = Sex|Age;
RUN;

PROC CORR DATA=X;
RUN;

** The remaining code is for VIF purposes only;

/* PROC REG does not accept CLASS statements or
   interactions, so we have to construct these
   ourselves :-(       */
DATA Donner;
  SET Donner;
  Male = (Sex eq "Male");
  Died = (Status eq "Died");
  Interaction = Male*Age;
RUN;

PROC REG DATA=Donner;
  MODEL Died = Male Age Interaction / VIF;
RUN;

/* In practice, the above is typically good enough,
   but a proper calculation needs to incorporate weights */
PROC LOGISTIC DATA=donner;
  CLASS Status Sex;
  MODEL Status = Sex|Age;
  OUTPUT OUT=fit P=pi;
RUN;

DATA Donner;
  SET fit;
  w = pi*(1-pi);
RUN;

PROC REG DATA=Donner;
  WEIGHT w;
  MODEL Died = Male Age Interaction / VIF;
RUN;