DATA donner;
  SET donner;
  Male = 1*(Sex='Male');
  Female = 1*(Sex='Female');
  Died = 1*(Status='Died');
  Age30 = Age - 30;
  Age45 = Age - 45;
RUN;

/*****************************/
/** Inference for beta      **/
/*****************************/
/* Wald */
PROC GENMOD DATA=donner;
  MODEL Died = Female|Age / DIST=BIN;
RUN;
/* LR */
PROC GENMOD DATA=donner;
  MODEL Died = Female|Age / DIST=BIN LRCI TYPE3;
RUN;

/*****************************/
/** LRTs                    **/
/*****************************/
/* Age effect in females? */
PROC GENMOD DATA=donner;
  MODEL Died = Male|Age / DIST=BIN LRCI TYPE3;
RUN;
/* Sex difference at age 30? */
PROC GENMOD DATA=donner;
  MODEL Died = Male|Age30 / DIST=BIN LRCI TYPE3;
RUN;
/* Sex difference at age 45? */
PROC GENMOD DATA=donner;
  MODEL Died = Male|Age45 / DIST=BIN LRCI TYPE3;
RUN;

/*****************************/
/** Probabilities           **/
/*****************************/
PROC GENMOD DATA=donner;
  MODEL Died = Male|Age / DIST=BIN;
  ESTIMATE '20yo male' Intercept 1 Male 1 Age 20 Male*Age 20;
  ESTIMATE '40yo male' Intercept 1 Male 1 Age 40 Male*Age 40;
  ESTIMATE '60yo male' Intercept 1 Male 1 Age 60 Male*Age 60;
  ESTIMATE '20yo female' Intercept 1 Age 20;
  ESTIMATE '40yo female' Intercept 1 Age 40;
  ESTIMATE '60yo female' Intercept 1 Age 60;
RUN;

/*****************************/
/** Odds ratios             **/
/*****************************/
PROC LOGISTIC DATA=donner;
  MODEL Died = Female|Age;
  UNITS Age=10;
  ODDSRATIO '10-year diff for males' Age / AT (Female=0) CL=PL;
  ODDSRATIO '10-year diff for females' Age / AT (Female=1) CL=PL;
  ODDSRATIO 'Male-female diff for 30yo' Female / AT (Age=30) CL=PL;
  CONTRAST '60yo male vs. 20yo female' Age -40 Female 1 Female*Age 20 / ESTIMATE=EXP;
RUN;